ASM杂项集合【802/绿宝石】

本站第一萌新 · 发表于 2020-5-3 15:12:30

本帖最后由本站第一萌新于 2020-5-3 15:19 编辑

绿宝石802专享：
这个源码使用了802的三属性框架，当然现在回头看这并不是最优的方法
制作觉醒石系统，携带对应属性觉醒石的精灵可以在战斗中获得额外属性
也是好久前写的代码了，和上面一样，不修改了

.gba
.thumb
.include "header/ArmipsBSMacros.asm"
.create "3.0.gba",0x8000000
.close
.open "test.gba","3.0.gba", 0x8000000
.org 0x08F80000
CheckHasAwakeningStone:
mov r0, #0x58
mul r0, r4
ldr r1, =(0x02024084 + 0x2E)
add r0, r1
ldrh r0, [r0]
mov r1, #80
lsl r1, #3
add r1, #18
cmp r0, r1 ;0x292
bgt HasNoAwakeningStone
sub r1, #17
cmp r0, r1 ;0x281
blt HasNoAwakeningStone
push {r5}
sub r5, r0, r1
ldr r1, =(0x08FC2C7C + 0x28)
mov r2, #0x2C
mul r0, r2
ldrb r0, [r0, r1]
ldr r3, =0x02024218
ldr r3, [r3]
mov r2, #0x24
mul r2, r4
add r1, r3, r2
add r1, #6
strb r0, [r1]
add r3, #0x9F
strb r4, [r3]
ldr r0, =(0x02024332 + 0x05)
strb r5, [r0]
pop {r5}
ldr r0, =BS_HASSTONE
ldr r3, =(0x08E073E4|1)
bl call_bx
ldr r3, =(0x08E19B64|1)
bx r3
HasNoAwakeningStone:
cmp r5, #0x95
beq GotoSub8E19B6A
bhi GotoSub8E19AEE
cmp r5, #0x20
ldr r3, =(0x08E19AD4|1)
bx r3
GotoSub8E19B6A:
ldr r3, =(0x08E19B6A|1)
bx r3
GotoSub8E19AEE:
ldr r3, =(0x08E19AEE|1)
bx r3
.pool
MoreBattlestring:
mov r3, #147
lsl r3, #2
add r1 ,r3, #1
cmp r0, r3
bgt More
mov r3, #0x7C
add r3, #0xFF
cmp r0, r3
bls GotoSub8E06654
ldr r3, =(0x08E0664C|1)
bx r3
More:
ldr r3, =NewBattleStringsTable
sub r0, r1
ldr r1, =(0x08E06658|1)
bx r1
GotoSub8E06654:
ldr r3, =(0x08E06654|1)
bx r3
.pool
call_bx:
bx r3
.pool
BS_HASSTONE:
printfromtable AwakeningStoneType
waitmessage 0x40
end3
STR_SUMMARY_NORMAL:
.byte 0x09, 0xD2, 0x04, 0x83, 0x0B, 0x43, 0x01, 0x63, 0x07, 0xD7, 0x09, 0x66, 0x0F, 0xE6, 0x10, 0x30, 0xFE, 0x03, 0x5C, 0x10, 0xA1, 0x07, 0xA5, 0x0E, 0x5C, 0x0F, 0x0B, 0x01, 0x42, 0x0C, 0x39, 0x0E, 0x5F, 0xFE, 0x03, 0x0B, 0x0B, 0xCF, 0x0A, 0xA1, 0x03, 0x07, 0x07, 0x8F, 0xAD, 0xFF
STR_SUMMARY_FIGHT:
.byte 0x09, 0xD2, 0x04, 0x83, 0x0B, 0x43, 0x01, 0x63, 0x07, 0xD7, 0x09, 0x66, 0x0F, 0xE6, 0x10, 0x30, 0xFE, 0x03, 0x5C, 0x10, 0xA1, 0x07, 0xA5, 0x0E, 0x5C, 0x04, 0x5B, 0x03, 0x5C, 0x0C, 0x39, 0x0E, 0x5F, 0xFE, 0x03, 0x0B, 0x0B, 0xCF, 0x0A, 0xA1, 0x03, 0x07, 0x07, 0x8F, 0xAD, 0xFF
STR_SUMMARY_FLYING:
.byte 0x09, 0xD2, 0x04, 0x83, 0x0B, 0x43, 0x01, 0x63, 0x07, 0xD7, 0x09, 0x66, 0x0F, 0xE6, 0x10, 0x30, 0xFE, 0x03, 0x5C, 0x10, 0xA1, 0x07, 0xA5, 0x0E, 0x5C, 0x03, 0xCC, 0x0E, 0x5B, 0x0C, 0x39, 0x0E, 0x5F, 0xFE, 0x03, 0x0B, 0x0B, 0xCF, 0x0A, 0xA1, 0x03, 0x07, 0x07, 0x8F, 0xAD, 0xFF
STR_SUMMARY_POISON:
.byte 0x09, 0xD2, 0x04, 0x83, 0x0B, 0x43, 0x01, 0x63, 0x07, 0xD7, 0x09, 0x66, 0x0F, 0xE6, 0x10, 0x30, 0xFE, 0x03, 0x5C, 0x10, 0xA1, 0x07, 0xA5, 0x0E, 0x5C, 0x03, 0x63, 0x0C, 0x39, 0x0E, 0x5F, 0xFE, 0x03, 0x0B, 0x0B, 0xCF, 0x0A, 0xA1, 0x03, 0x07, 0x07, 0x8F, 0xAD, 0xFF
STR_SUMMARY_GROUND:
.byte 0x09, 0xD2, 0x04, 0x83, 0x0B, 0x43, 0x01, 0x63, 0x07, 0xD7, 0x09, 0x66, 0x0F, 0xE6, 0x10, 0x30, 0xFE, 0x03, 0x5C, 0x10, 0xA1, 0x07, 0xA5, 0x0E, 0x5C, 0x03, 0x1F, 0x09, 0x7E, 0x0C, 0x39, 0x0E, 0x5F, 0xFE, 0x03, 0x0B, 0x0B, 0xCF, 0x0A, 0xA1, 0x03, 0x07, 0x07, 0x8F, 0xAD, 0xFF
STR_SUMMARY_ROCK:
.byte 0x09, 0xD2, 0x04, 0x83, 0x0B, 0x43, 0x01, 0x63, 0x07, 0xD7, 0x09, 0x66, 0x0F, 0xE6, 0x10, 0x30, 0xFE, 0x03, 0x5C, 0x10, 0xA1, 0x07, 0xA5, 0x0E, 0x5C, 0x0E, 0xBB, 0x0B, 0xEB, 0x0C, 0x39, 0x0E, 0x5F, 0xFE, 0x03, 0x0B, 0x0B, 0xCF, 0x0A, 0xA1, 0x03, 0x07, 0x07, 0x8F, 0xAD, 0xFF
STR_SUMMARY_BUG:
.byte 0x09, 0xD2, 0x04, 0x83, 0x0B, 0x43, 0x01, 0x63, 0x07, 0xD7, 0x09, 0x66, 0x0F, 0xE6, 0x10, 0x30, 0xFE, 0x03, 0x5C, 0x10, 0xA1, 0x07, 0xA5, 0x0E, 0x5C, 0x02, 0x68, 0x0C, 0x39, 0x0E, 0x5F, 0xFE, 0x03, 0x0B, 0x0B, 0xCF, 0x0A, 0xA1, 0x03, 0x07, 0x07, 0x8F, 0xAD, 0xFF
STR_SUMMARY_GHOST:
.byte 0x09, 0xD2, 0x04, 0x83, 0x0B, 0x43, 0x01, 0x63, 0x07, 0xD7, 0x09, 0x66, 0x0F, 0xE6, 0x10, 0x30, 0xFE, 0x03, 0x5C, 0x10, 0xA1, 0x07, 0xA5, 0x0E, 0x5C, 0x04, 0xB5, 0x0C, 0x39, 0x0E, 0x5F, 0xFE, 0x03, 0x0B, 0x0B, 0xCF, 0x0A, 0xA1, 0x03, 0x07, 0x07, 0x8F, 0xAD, 0xFF
STR_SUMMARY_STEEL:
.byte 0x09, 0xD2, 0x04, 0x83, 0x0B, 0x43, 0x01, 0x63, 0x07, 0xD7, 0x09, 0x66, 0x0F, 0xE6, 0x10, 0x30, 0xFE, 0x03, 0x5C, 0x10, 0xA1, 0x07, 0xA5, 0x0E, 0x5C, 0x04, 0x40, 0x0C, 0x39, 0x0E, 0x5F, 0xFE, 0x03, 0x0B, 0x0B, 0xCF, 0x0A, 0xA1, 0x03, 0x07, 0x07, 0x8F, 0xAD, 0xFF
STR_SUMMARY_FIRE:
.byte 0x09, 0xD2, 0x04, 0x83, 0x0B, 0x43, 0x01, 0x63, 0x07, 0xD7, 0x09, 0x66, 0x0F, 0xE6, 0x10, 0x30, 0xFE, 0x03, 0x5C, 0x10, 0xA1, 0x07, 0xA5, 0x0E, 0x5C, 0x05, 0x7D, 0x0C, 0x39, 0x0E, 0x5F, 0xFE, 0x03, 0x0B, 0x0B, 0xCF, 0x0A, 0xA1, 0x03, 0x07, 0x07, 0x8F, 0xAD, 0xFF
STR_SUMMARY_WATER:
.byte 0x09, 0xD2, 0x04, 0x83, 0x0B, 0x43, 0x01, 0x63, 0x07, 0xD7, 0x09, 0x66, 0x0F, 0xE6, 0x10, 0x30, 0xFE, 0x03, 0x5C, 0x10, 0xA1, 0x07, 0xA5, 0x0E, 0x5C, 0x0C, 0x51, 0x0C, 0x39, 0x0E, 0x5F, 0xFE, 0x03, 0x0B, 0x0B, 0xCF, 0x0A, 0xA1, 0x03, 0x07, 0x07, 0x8F, 0xAD, 0xFF
STR_SUMMARY_GRASS:
.byte 0x09, 0xD2, 0x04, 0x83, 0x0B, 0x43, 0x01, 0x63, 0x07, 0xD7, 0x09, 0x66, 0x0F, 0xE6, 0x10, 0x30, 0xFE, 0x03, 0x5C, 0x10, 0xA1, 0x07, 0xA5, 0x0E, 0x5C, 0x02, 0x01, 0x0C, 0x39, 0x0E, 0x5F, 0xFE, 0x03, 0x0B, 0x0B, 0xCF, 0x0A, 0xA1, 0x03, 0x07, 0x07, 0x8F, 0xAD, 0xFF
STR_SUMMARY_ELECTRIC:
.byte 0x09, 0xD2, 0x04, 0x83, 0x0B, 0x43, 0x01, 0x63, 0x07, 0xD7, 0x09, 0x66, 0x0F, 0xE6, 0x10, 0x30, 0xFE, 0x03, 0x5C, 0x10, 0xA1, 0x07, 0xA5, 0x0E, 0x5C, 0x03, 0x2E, 0x0C, 0x39, 0x0E, 0x5F, 0xFE, 0x03, 0x0B, 0x0B, 0xCF, 0x0A, 0xA1, 0x03, 0x07, 0x07, 0x8F, 0xAD, 0xFF
STR_SUMMARY_PSYCHIC:
.byte 0x09, 0xD2, 0x04, 0x83, 0x0B, 0x43, 0x01, 0x63, 0x07, 0xD7, 0x09, 0x66, 0x0F, 0xE6, 0x10, 0x30, 0xFE, 0x03, 0x5C, 0x10, 0xA1, 0x07, 0xA5, 0x0E, 0x5C, 0x02, 0x2E, 0x09, 0xD2, 0x0C, 0x39, 0x0E, 0x5F, 0xFE, 0x03, 0x0B, 0x0B, 0xCF, 0x0A, 0xA1, 0x03, 0x07, 0x07, 0x8F, 0xAD, 0xFF
STR_SUMMARY_ICE:
.byte 0x09, 0xD2, 0x04, 0x83, 0x0B, 0x43, 0x01, 0x63, 0x07, 0xD7, 0x09, 0x66, 0x0F, 0xE6, 0x10, 0x30, 0xFE, 0x03, 0x5C, 0x10, 0xA1, 0x07, 0xA5, 0x0E, 0x5C, 0x01, 0xB6, 0x0C, 0x39, 0x0E, 0x5F, 0xFE, 0x03, 0x0B, 0x0B, 0xCF, 0x0A, 0xA1, 0x03, 0x07, 0x07, 0x8F, 0xAD, 0xFF
STR_SUMMARY_DRAGON:
.byte 0x09, 0xD2, 0x04, 0x83, 0x0B, 0x43, 0x01, 0x63, 0x07, 0xD7, 0x09, 0x66, 0x0F, 0xE6, 0x10, 0x30, 0xFE, 0x03, 0x5C, 0x10, 0xA1, 0x07, 0xA5, 0x0E, 0x5C, 0x08, 0xCD, 0x0C, 0x39, 0x0E, 0x5F, 0xFE, 0x03, 0x0B, 0x0B, 0xCF, 0x0A, 0xA1, 0x03, 0x07, 0x07, 0x8F, 0xAD, 0xFF
STR_SUMMARY_DARK:
.byte 0x09, 0xD2, 0x04, 0x83, 0x0B, 0x43, 0x01, 0x63, 0x07, 0xD7, 0x09, 0x66, 0x0F, 0xE6, 0x10, 0x30, 0xFE, 0x03, 0x5C, 0x10, 0xA1, 0x07, 0xA5, 0x0E, 0x5C, 0x03, 0x96, 0x0C, 0x39, 0x0E, 0x5F, 0xFE, 0x03, 0x0B, 0x0B, 0xCF, 0x0A, 0xA1, 0x03, 0x07, 0x07, 0x8F, 0xAD, 0xFF
STR_SUMMARY_FAIRY:
.byte 0x09, 0xD2, 0x04, 0x83, 0x0B, 0x43, 0x01, 0x63, 0x07, 0xD7, 0x09, 0x66, 0x0F, 0xE6, 0x10, 0x30, 0xFE, 0x03, 0x5C, 0x10, 0xA1, 0x07, 0xA5, 0x0E, 0x5C, 0x0E, 0xE6, 0x07, 0x5B, 0x0C, 0x39, 0x0E, 0x5F, 0xFE, 0x03, 0x0B, 0x0B, 0xCF, 0x0A, 0xA1, 0x03, 0x07, 0x07, 0x8F, 0xAD, 0xFF
STR_USE_NORMAL:
.byte 0xFD, 0x12, 0x07, 0xA5, 0x0E, 0x5C, 0x08, 0x9E, 0x0F, 0x0B, 0x01, 0x42, 0x0C, 0x39, 0x0E, 0x5F, 0xAB, 0xFF
STR_USE_FIGHT:
.byte 0xFD, 0x12, 0x07, 0xA5, 0x0E, 0x5C, 0x08, 0x9E, 0x04, 0x5B, 0x03, 0x5C, 0x0C, 0x39, 0x0E, 0x5F, 0xAB, 0xFF
STR_USE_FLYING:
.byte 0xFD, 0x12, 0x07, 0xA5, 0x0E, 0x5C, 0x08, 0x9E, 0x03, 0xCC, 0x0E, 0x5B, 0x0C, 0x39, 0x0E, 0x5F, 0xAB, 0xFF
STR_USE_POISON:
.byte 0xFD, 0x12, 0x07, 0xA5, 0x0E, 0x5C, 0x08, 0x9E, 0x03, 0x63, 0x0C, 0x39, 0x0E, 0x5F, 0xAB, 0xFF
STR_USE_GROUND:
.byte 0xFD, 0x12, 0x07, 0xA5, 0x0E, 0x5C, 0x08, 0x9E, 0x03, 0x1F, 0x09, 0x7E, 0x0C, 0x39, 0x0E, 0x5F, 0xAB, 0xFF
STR_USE_ROCK:
.byte 0xFD, 0x12, 0x07, 0xA5, 0x0E, 0x5C, 0x08, 0x9E, 0x0E, 0xBB, 0x0B, 0xEB, 0x0C, 0x39, 0x0E, 0x5F, 0xAB, 0xFF
STR_USE_BUG:
.byte 0xFD, 0x12, 0x07, 0xA5, 0x0E, 0x5C, 0x08, 0x9E, 0x02, 0x68, 0x0C, 0x39, 0x0E, 0x5F, 0xAB, 0xFF
STR_USE_GHOST:
.byte 0xFD, 0x12, 0x07, 0xA5, 0x0E, 0x5C, 0x08, 0x9E, 0x04, 0xB5, 0x0C, 0x39, 0x0E, 0x5F, 0xAB, 0xFF
STR_USE_STEEL:
.byte 0xFD, 0x12, 0x07, 0xA5, 0x0E, 0x5C, 0x08, 0x9E, 0x04, 0x40, 0x0C, 0x39, 0x0E, 0x5F, 0xAB, 0xFF
STR_USE_FIRE:
.byte 0xFD, 0x12, 0x07, 0xA5, 0x0E, 0x5C, 0x08, 0x9E, 0x05, 0x7D, 0x0C, 0x39, 0x0E, 0x5F, 0xAB, 0xFF
STR_USE_WATER:
.byte 0xFD, 0x12, 0x07, 0xA5, 0x0E, 0x5C, 0x08, 0x9E, 0x0C, 0x51, 0x0C, 0x39, 0x0E, 0x5F, 0xAB, 0xFF
STR_USE_GRASS:
.byte 0xFD, 0x12, 0x07, 0xA5, 0x0E, 0x5C, 0x08, 0x9E, 0x02, 0x01, 0x0C, 0x39, 0x0E, 0x5F, 0xAB, 0xFF
STR_USE_ELECTRIC:
.byte 0xFD, 0x12, 0x07, 0xA5, 0x0E, 0x5C, 0x08, 0x9E, 0x03, 0x2E, 0x0C, 0x39, 0x0E, 0x5F, 0xAB, 0xFF
STR_USE_PSYCHIC:
.byte 0xFD, 0x12, 0x07, 0xA5, 0x0E, 0x5C, 0x08, 0x9E, 0x02, 0x2E, 0x09, 0xD2, 0x0C, 0x39, 0x0E, 0x5F, 0xAB, 0xFF
STR_USE_ICE:
.byte 0xFD, 0x12, 0x07, 0xA5, 0x0E, 0x5C, 0x08, 0x9E, 0x01, 0xB6, 0x0C, 0x39, 0x0E, 0x5F, 0xAB, 0xFF
STR_USE_DRAGON:
.byte 0xFD, 0x12, 0x07, 0xA5, 0x0E, 0x5C, 0x08, 0x9E, 0x08, 0xCD, 0x0C, 0x39, 0x0E, 0x5F, 0xAB, 0xFF
STR_USE_DARK:
.byte 0xFD, 0x12, 0x07, 0xA5, 0x0E, 0x5C, 0x08, 0x9E, 0x03, 0x96, 0x0C, 0x39, 0x0E, 0x5F, 0xAB, 0xFF
STR_USE_FAIRY:
.byte 0xFD, 0x12, 0x07, 0xA5, 0x0E, 0x5C, 0x08, 0x9E, 0x0E, 0xE6, 0x07, 0x5B, 0x0C, 0x39, 0x0E, 0x5F, 0xAB, 0xFF
.align 4
NewBattleStringsTable:
.word STR_USE_NORMAL
.word STR_USE_FIGHT
.word STR_USE_FLYING
.word STR_USE_POISON
.word STR_USE_GROUND
.word STR_USE_ROCK
.word STR_USE_BUG
.word STR_USE_GHOST
.word STR_USE_STEEL
.word STR_USE_FIRE
.word STR_USE_WATER
.word STR_USE_GRASS
.word STR_USE_ELECTRIC
.word STR_USE_PSYCHIC
.word STR_USE_ICE
.word STR_USE_DRAGON
.word STR_USE_DARK
.word STR_USE_FAIRY
.word 0x00
AwakeningStoneType:
.halfword 0x24D, 0x24E, 0x24F, 0x250, 0x251, 0x252, 0x253, 0x254, 0x255, 0x256, 0x257, 0x258, 0x259, 0x25A, 0x25B, 0x25C, 0x25D, 0x25E
.align 4
StonePic:
.word 0x00012010, 0xF0000036, 0xC0078001, 0x0F0013F0, 0x00CC04CC, 0x00BBBBCC, 0xD4BBBB02, 0x07701DF0
.word 0xBC12300C, 0x88C00330, 0x0003B090, 0xBB03108C, 0x00BBABAB, 0xBBBA8BBB, 0xBB88AB8B, 0xA88A8A00
.word 0x88A8A8B8, 0x888800A8, 0x8A88B88A, 0x8805B888, 0xCBB8A888, 0x009B5600, 0x00BB765A, 0x1003904C
.word 0xA3F0C817, 0x0F8801E0, 0xCC888888, 0xB3100200, 0xA3601EF0, 0x4001F0C0, 0x00000001
.align 4
StonePal:
.word 0x00002010, 0xFF7FFF00, 0x1F7C1F03, 0x7FE00000, 0x7C0003E0, 0xFF000000, 0x1A1B7E3F, 0x302B9F1B
.word 0x190022B9, 0x00000100
.org 0x08E19ACC
ldr r3, =(CheckHasAwakeningStone|1)
bx r3
.pool
.org 0x08E06644
ldr r3, =(MoreBattlestring|1)
bx r3
.pool
.org (0x08FC9AA8 + 0x2C * 0x00)
.byte 0x07, 0xA5, 0x0E, 0x5C, 0x0B, 0xEB, 0x00, 0x0F, 0x0B, 0x01, 0x42, 0xFF, 0x00, 0x00
.org (0x08FC9ABC + 0x2C * 0x00)
.word STR_SUMMARY_NORMAL
.org (0x08FC9AD0 + 0x2C * 0x00)
.byte 0x00
.org (0x08FCD3FC + 0x08 * 0x00)
.word StonePic
.word StonePal
.org (0x08FC9AA8 + 0x2C * 0x01)
.byte 0x07, 0xA5, 0x0E, 0x5C, 0x0B, 0xEB, 0x00, 0x04, 0x5B, 0x03, 0x5C, 0xFF, 0x00, 0x00
.org (0x08FC9ABC + 0x2C * 0x01)
.word STR_SUMMARY_FIGHT
.org (0x08FC9AD0 + 0x2C * 0x01)
.byte 0x01
.org (0x08FCD3FC + 0x08 * 0x01)
.word StonePic
.word StonePal
.org (0x08FC9AA8 + 0x2C * 0x02)
.byte 0x07, 0xA5, 0x0E, 0x5C, 0x0B, 0xEB, 0x00, 0x03, 0xCC, 0x0E, 0x5B, 0xFF, 0x00, 0x00
.org (0x08FC9ABC + 0x2C * 0x02)
.word STR_SUMMARY_FLYING
.org (0x08FC9AD0 + 0x2C * 0x02)
.byte 0x02
.org (0x08FCD3FC + 0x08 * 0x02)
.word StonePic
.word StonePal
.org (0x08FC9AA8 + 0x2C * 0x03)
.byte 0x07, 0xA5, 0x0E, 0x5C, 0x0B, 0xEB, 0x00, 0x03, 0x63, 0xFF, 0x00, 0x00, 0x00, 0x00
.org (0x08FC9ABC + 0x2C * 0x03)
.word STR_SUMMARY_POISON
.org (0x08FC9AD0 + 0x2C * 0x03)
.byte 0x03
.org (0x08FCD3FC + 0x08 * 0x03)
.word StonePic
.word StonePal
.org (0x08FC9AA8 + 0x2C * 0x04)
.byte 0x07, 0xA5, 0x0E, 0x5C, 0x0B, 0xEB, 0x00, 0x03, 0x1F, 0x09, 0x7E, 0xFF, 0x00, 0x00
.org (0x08FC9ABC + 0x2C * 0x04)
.word STR_SUMMARY_GROUND
.org (0x08FC9AD0 + 0x2C * 0x04)
.byte 0x04
.org (0x08FCD3FC + 0x08 * 0x04)
.word StonePic
.word StonePal
.org (0x08FC9AA8 + 0x2C * 0x05)
.byte 0x07, 0xA5, 0x0E, 0x5C, 0x0B, 0xEB, 0x00, 0x0E, 0xBB, 0x0B, 0xEB, 0xFF, 0x00, 0x00
.org (0x08FC9ABC + 0x2C * 0x05)
.word STR_SUMMARY_ROCK
.org (0x08FC9AD0 + 0x2C * 0x05)
.byte 0x05
.org (0x08FCD3FC + 0x08 * 0x05)
.word StonePic
.word StonePal
.org (0x08FC9AA8 + 0x2C * 0x06)
.byte 0x07, 0xA5, 0x0E, 0x5C, 0x0B, 0xEB, 0x00, 0x02, 0x68, 0xFF, 0x00, 0x00, 0x00, 0x00
.org (0x08FC9ABC + 0x2C * 0x06)
.word STR_SUMMARY_BUG
.org (0x08FC9AD0 + 0x2C * 0x06)
.byte 0x06
.org (0x08FCD3FC + 0x08 * 0x06)
.word StonePic
.word StonePal
.org (0x08FC9AA8 + 0x2C * 0x07)
.byte 0x07, 0xA5, 0x0E, 0x5C, 0x0B, 0xEB, 0x00, 0x04, 0xB5, 0xFF, 0x00, 0x00, 0x00, 0x00
.org (0x08FC9ABC + 0x2C * 0x07)
.word STR_SUMMARY_GHOST
.org (0x08FC9AD0 + 0x2C * 0x07)
.byte 0x07
.org (0x08FCD3FC + 0x08 * 0x07)
.word StonePic
.word StonePal
.org (0x08FC9AA8 + 0x2C * 0x08)
.byte 0x07, 0xA5, 0x0E, 0x5C, 0x0B, 0xEB, 0x00, 0x04, 0x40, 0xFF, 0x00, 0x00, 0x00, 0x00
.org (0x08FC9ABC + 0x2C * 0x08)
.word STR_SUMMARY_STEEL
.org (0x08FC9AD0 + 0x2C * 0x08)
.byte 0x08
.org (0x08FCD3FC + 0x08 * 0x08)
.word StonePic
.word StonePal
.org (0x08FC9AA8 + 0x2C * 0x09)
.byte 0x07, 0xA5, 0x0E, 0x5C, 0x0B, 0xEB, 0x00, 0x05, 0x7D, 0xFF, 0x00, 0x00, 0x00, 0x00
.org (0x08FC9ABC + 0x2C * 0x09)
.word STR_SUMMARY_FIRE
.org (0x08FC9AD0 + 0x2C * 0x09)
.byte 0x0A
.org (0x08FCD3FC + 0x08 * 0x09)
.word StonePic
.word StonePal
.org (0x08FC9AA8 + 0x2C * 0x0A)
.byte 0x07, 0xA5, 0x0E, 0x5C, 0x0B, 0xEB, 0x00, 0x0C, 0x51, 0xFF, 0x00, 0x00, 0x00, 0x00
.org (0x08FC9ABC + 0x2C * 0x0A)
.word STR_SUMMARY_WATER
.org (0x08FC9AD0 + 0x2C * 0x0A)
.byte 0x0B
.org (0x08FCD3FC + 0x08 * 0x0A)
.word StonePic
.word StonePal
.org (0x08FC9AA8 + 0x2C * 0x0B)
.byte 0x07, 0xA5, 0x0E, 0x5C, 0x0B, 0xEB, 0x00, 0x02, 0x01, 0xFF, 0x00, 0x00, 0x00, 0x00
.org (0x08FC9ABC + 0x2C * 0x0B)
.word STR_SUMMARY_GRASS
.org (0x08FC9AD0 + 0x2C * 0x0B)
.byte 0x0C
.org (0x08FCD3FC + 0x08 * 0x0B)
.word StonePic
.word StonePal
.org (0x08FC9AA8 + 0x2C * 0x0C)
.byte 0x07, 0xA5, 0x0E, 0x5C, 0x0B, 0xEB, 0x00, 0x03, 0x2E, 0xFF, 0x00, 0x00, 0x00, 0x00
.org (0x08FC9ABC + 0x2C * 0x0C)
.word STR_SUMMARY_ELECTRIC
.org (0x08FC9AD0 + 0x2C * 0x0C)
.byte 0x0D
.org (0x08FCD3FC + 0x08 * 0x0C)
.word StonePic
.word StonePal
.org (0x08FC9AA8 + 0x2C * 0x0D)
.byte 0x07, 0xA5, 0x0E, 0x5C, 0x0B, 0xEB, 0x00, 0x02, 0x2E, 0x09, 0xD2, 0xFF, 0x00, 0x00
.org (0x08FC9ABC + 0x2C * 0x0D)
.word STR_SUMMARY_PSYCHIC
.org (0x08FC9AD0 + 0x2C * 0x0D)
.byte 0x0E
.org (0x08FCD3FC + 0x08 * 0x0D)
.word StonePic
.word StonePal
.org (0x08FC9AA8 + 0x2C * 0x0E)
.byte 0x07, 0xA5, 0x0E, 0x5C, 0x0B, 0xEB, 0x00, 0x01, 0xB6, 0xFF, 0x00, 0x00, 0x00, 0x00
.org (0x08FC9ABC + 0x2C * 0x0E)
.word STR_SUMMARY_ICE
.org (0x08FC9AD0 + 0x2C * 0x0E)
.byte 0x0F
.org (0x08FCD3FC + 0x08 * 0x0E)
.word StonePic
.word StonePal
.org (0x08FC9AA8 + 0x2C * 0x0F)
.byte 0x07, 0xA5, 0x0E, 0x5C, 0x0B, 0xEB, 0x00, 0x08, 0xCD, 0xFF, 0x00, 0x00, 0x00, 0x00
.org (0x08FC9ABC + 0x2C * 0x0F)
.word STR_SUMMARY_DRAGON
.org (0x08FC9AD0 + 0x2C * 0x0F)
.byte 0x010
.org (0x08FCD3FC + 0x08 * 0x0F)
.word StonePic
.word StonePal
.org (0x08FC9AA8 + 0x2C * 0x10)
.byte 0x07, 0xA5, 0x0E, 0x5C, 0x0B, 0xEB, 0x00, 0x03, 0x96, 0xFF, 0x00, 0x00, 0x00, 0x00
.org (0x08FC9ABC + 0x2C * 0x10)
.word STR_SUMMARY_DARK
.org (0x08FC9AD0 + 0x2C * 0x10)
.byte 0x11
.org (0x08FCD3FC + 0x08 * 0x10)
.word StonePic
.word StonePal
.org (0x08FC9AA8 + 0x2C * 0x11)
.byte 0x07, 0xA5, 0x0E, 0x5C, 0x0B, 0xEB, 0x00, 0x0E, 0xE6, 0x07, 0x5B, 0xFF, 0x00, 0x00
.org (0x08FC9ABC + 0x2C * 0x11)
.word STR_SUMMARY_FAIRY
.org (0x08FC9AD0 + 0x2C * 0x11)
.byte 0x17
.org (0x08FCD3FC + 0x08 * 0x11)
.word StonePic
.word StonePal
.close

复制代码

本站第一萌新 · 发表于 2020-5-4 15:01:57

本帖最后由本站第一萌新于 2020-5-4 15:06 编辑

输入脚本地址，执行脚本
也是和初始村蓝胖对话查看效果
顺便说一下，我是因为偷懒才这么搞得。如果你想作用于其他NPC，请删掉

.org 0x089C0DFC
.word Script_ScriptRunner

复制代码

并将Script_ScriptRunner给你想要的NPC

.gba
.thumb
.loadtable "header/CharTable.txt"
.include "header/ArmipsMacros.asm"
.create "3.0.gba",0x8000000
.close
.open "test.gba","3.0.gba", 0x8000000
.org 0x08F80000
.func ScriptRunner
push {r4-r5, lr}
ldr r0, =(Task_SRProcessInput|1)
mov r1, #0
ldr r4, =(0x080A8FB0|1)
bl call_bx
ldr r5, =0x03005E00
mov r1, #40
mul r0, r1
add r5, r0
mov r0, #0 ;X
mov r1, #0 ;Y
mov r2, #8 ;W
mov r3, #2 ;H
ldr r4, =(0x080E2A1C|1)
bl call_bx
strh r0, [r5, #8] ;twindowId
mov r1, #0
strh r1, [r5, #10] ;tstate
str r1, [r5, #12] ;tpointer
strh r1, [r5, #16] ;tslot
mov r1, #0
ldr r4, =(0x08197854|1)
bl call_bx
mov r0, #0
ldr r4, =(0x081999BC|1)
bl call_bx
pop {r4-r5, pc}
.endfunc
.pool
.func Task_SRProcessInput
push {r4-r7, lr}
mov r5, r0
ldr r7, =0x03005E00
mov r1, #40
mul r0, r1
add r7, r0
ldrh r6, [r7, #8] ;twindowId
ldrh r0, [r7, #10] ;tstate
cmp r0, #0
beq ShowScriptRunner
ldr r0, =0x030022C0
ldrh r0, [r0, #0x2E]
cmp r0, #1
beq A_Pressed
cmp r0, #2
beq B_Pressed
cmp r0, #0x10
beq Right_Pressed
cmp r0, #0x20
beq Left_Pressed
cmp r0, #0x40
beq Up_Pressed
cmp r0, #0x80
beq Down_Pressed
b InputEnd
A_Pressed:
ldr r0, =0x020375E0
strh r5, [r0]
mov r1, #1
strh r1, [r0, #0x10]
b InputEnd ;理论上这里应该先把window free了，但是懒得改了
B_Pressed:
mov r0, r5
mov r1, r6
bl DeleteTaskAndFreeWindow
ldr r0, =0x020375E0
mov r1, #0
strh r1, [r0, #0x10]
b InputEnd
Right_Pressed:
ldrh r0, [r7, #16]
cmp r0, #3
bge InputEnd
add r0, #1
strh r0, [r7, #16]
mov r2, r0
ldr r0, [r7, #12]
mov r1, r6
bl ShowPointer
b InputEnd
Left_Pressed:
ldrh r0, [r7, #16]
cmp r0, #0
ble InputEnd
sub r0, #1
strh r0, [r7, #16]
mov r2, r0
ldr r0, [r7, #12]
mov r1, r6
bl ShowPointer
b InputEnd
Up_Pressed:
ldrh r0, [r7, #16]
mov r1, #3
sub r1, r0
mov r2, r7
add r2, #12
ldrb r0, [r2, r1]
cmp r0, #0xFF
bge InputEnd
add r0, #1
strb r0, [r2, r1]
ldr r0, [r7, #12]
mov r1, r6
ldrh r2, [r7, #16]
bl ShowPointer
b InputEnd
Down_Pressed:
ldrh r0, [r7, #16]
mov r1, #3
sub r1, r0
mov r2, r7
add r2, #12
ldrb r0, [r2, r1]
cmp r0, #0
ble InputEnd
sub r0, #1
strb r0, [r2, r1]
ldr r0, [r7, #12]
mov r1, r6
ldrh r2, [r7, #16]
bl ShowPointer
b InputEnd
ShowScriptRunner:
ldr r0, [r7, #12] ;tpointer
mov r1, r6 ;twindowId
ldrh r2, [r7, #16] ;tslot
bl ShowPointer
mov r0, #1
strh r0, [r7, #10]
InputEnd:
pop {r4-r7, pc}
.endfunc
.pool
.func ShowPointer
push {r4-r7, lr}
mov r4, r8
push {r4}
add sp, #-8
mov r5, r0
mov r8, r1
mov r6, r2
mov r0, r1
mov r1, #17
ldr r4, =(0x08003C48|1)
bl call_bx
mov r7, #0
PrintPointerLoop:
cmp r7, #4
bge LoopEnd
mov r0, #0xFF
mov r1, #8
mov r2, #3
sub r2, r7
mul r1, r2
lsl r0, r1
and r0, r5
lsr r0, r1
mov r1, r0
ldr r0, =0x02021FC4
mov r2, #2
mov r3, #2
ldr r4, =(0x08008E20|1)
bl call_bx
cmp r7, r6
bne NotHighLight
ldr r0, =0x02021EC4
ldr r1, =gText_HignLight
ldr r4, =(0x08008EE0|1)
bl call_bx
ldr r0, =0x02021EC4
ldr r1, =0x02021FC4
ldr r4, =(0x08008BC0|1)
bl call_bx
mov r0, #0
str r0, [sp]
str r0, [sp, #4]
mov r0, r8
ldr r1, =0x02021EC4
mov r2, #16
mul r2, r7
add r2, #1
mov r3, #1
ldr r4, =(0x080E04A4|1)
bl call_bx
b PrepareToNext
NotHighLight:
mov r0, #0
str r0, [sp]
str r0, [sp, #4]
mov r0, r8
ldr r1, =0x02021FC4
mov r2, #16
mul r2, r7
add r2, #1
mov r3, #1
ldr r4, =(0x080E04A4|1)
bl call_bx
PrepareToNext:
add r7, #1
b PrintPointerLoop
LoopEnd:
add sp, #8
pop {r4}
mov r8, r4
pop {r4-r7, pc}
.endfunc
.pool
.func RunScript
push {r4-r5, lr}
ldr r0, =0x020375E0
ldrh r0, [r0] ;taskId
ldr r2, =0x03005E00
mov r1, #40
mul r1, r0
add r2, r1
ldrh r1, [r2, #8]
ldr r5, [r2, #12]
bl DeleteTaskAndFreeWindow
mov r0, r5
ldr r4, =(0x08098EF8|1)
bl call_bx
pop {r4-r5, pc}
.endfunc
.pool
.func DeleteTaskAndFreeWindow
push {r4-r5, lr}
mov r5, r1
ldr r4, =(0x080A909C|1)
bl call_bx
mov r0, r5
ldr r4, =(0x080E2A78|1)
bl call_bx
pop {r4-r5, pc}
.endfunc
.pool
.func call_bx
bx r4
.endfunc
.pool
gText_HignLight:
.string "[文本色_红]"
Script_ScriptRunner:
lock
faceplayer
preparemsg gText_PleaseInput
waitmsg
callasm (ScriptRunner|1)
waitkeypress
compare 0x800D, 1
if1 0x1, Script_RunScript
msgbox gText_Cancel, 0x6
release
end
Script_RunScript:
release
callasm (RunScript|1)
.org 0x089C0DFC
.word Script_ScriptRunner
gText_PleaseInput:
.string "欢迎使用脚本执行器，\n请输入脚本地址："
gText_Cancel:
.string "输入取消！"
.close

复制代码

本站第一萌新 · 发表于 2020-5-4 20:26:16

入门时候写的，使得所有野生精灵（包括赠送精灵）变成闪光
不过指定PID的精灵好像不会有效果，不过我也懒得去改了

.gba
.thumb
.create "3.0.gba",0x8000000
.close
.open "test.gba","3.0.gba", 0x8000000
.org 0x08F80000
.func ShinyHack
push {r4-r6}
ldr r3, =(0x0806F5CC|1)
bl call_bx
mov r4, r0
ldr r3, =(0x0806F5CC|1)
bl call_bx
mov r5, #7
and r5, r0
ldr r3, =(0x080F0020|1)
bl call_bx
lsl r6, r0, #16
lsr r6, #16
lsr r0, #16
eor r0, r6
eor r0, r4
eor r0, r5
lsl r0, #16
orr r0, r4
mov r1, r0
pop {r4-r6}
ldr r3, =(0x0806AF8C|1)
bx r3
.endfunc
.pool
.func call_bx
bx r3
.endfunc
.pool
.org 0x0806AF84
ldr r3, =(ShinyHack|1)
bx r3
.pool
.close

复制代码

本站第一萌新 · 发表于 2020-5-5 20:26:35

显示觉醒力量属性（包括战斗中选择技能页面），威力
这一段代码还有很大的优化空间

.gba
.thumb
.create "3.0.gba",0x8000000
.close
.open "test.gba","3.0.gba", 0x8000000
.org 0x08F80000
.func SetMoveTypeIconsHack
cmp r0, #237
bne NotHiddenPower1
mov r0, #0
bl GetType
ldr r3, =(0x081C4448|1)
bx r3
NotHiddenPower1:
mov r1, r0
lsl r0, r1, #1
add r0, r1
lsl r0, #2
ldr r3, =(0x081C4444|1)
bx r3
.endfunc
.pool
.func MoveSelectionDisplayMoveTypeHack
cmp r2, #237
bne NotHiddenPower2
mov r4, r0
mov r0, #1
bl GetType
mov r2, r0
mov r0, r4
b Back
NotHiddenPower2:
lsl r1, r2, #1
add r1, r2
lsl r1, #2
add r1, r3
ldrb r2, [r1, #2]
Back:
ldr r3, =(0x08059BF2|1)
bx r3
.endfunc
.pool
.func PrintMovePowerHack
cmp r4, #237
bne NotHiddenPower3
bl GetPower
mov r1, r0
ldr r4, =0x02021CC4
ldr r3, =(0x081C3CA0|1)
bx r3
NotHiddenPower3:
add r2, r0, r2
ldrb r0, [r2, #1]
mov r6, r1
cmp r0, #1
ldr r3, =(0x081C3C8C|1)
bx r3
.endfunc
.pool
.func GetType ;r0 = isinbattle
push {r4-r5, lr}
add sp, #-12
cmp r0, #1
bne SummaryScreen
ldr r0, =0x02024064
ldrb r0, [r0]
ldr r3, =(0x08E1833C|1)
bl call_bx
b GetIvs1
SummaryScreen:
ldr r0, =0x0203CF1C
ldr r0, [r0]
add r0, #0xC
GetIvs1:
mov r1, sp
bl GetIvs
mov r4, #0
mov r5, #0
GetTypeLoop:
cmp r4, #6
bge GetTypeLoopEnd
mov r0, #1
lsl r1, r4, #1
mov r2, sp
ldrh r1, [r2, r1]
and r0, r1
lsl r0, r4
orr r5, r0
add r4, #1
b GetTypeLoop
GetTypeLoopEnd:
mov r0, #15
mul r0, r5
mov r1, #63
ldr r3, =(0x082E7B68|1)
bl call_bx
add r0, #1
cmp r0, #9
blt LessThanMy
add r0, #1
LessThanMy:
add sp, #12
pop {r4-r5, pc}
.endfunc
.pool
.func GetPower
push {r4-r5, lr}
add sp, #-12
ldr r0, =0x0203CF1C
ldr r0, [r0]
add r0, #0xC
mov r1, sp
bl GetIvs
mov r0, sp
ldrh r0, [r0]
mov r1, #2
and r0, r1
lsr r5, r0, #1
mov r4, #1
GetPowerLoop:
cmp r4, #6
bge GetPowerLoopEnd
mov r0, #2
lsl r1, r4, #1
mov r2, sp
ldrh r1, [r2, r1]
and r0, r1
sub r1, r4, #1
lsl r0, r1
orr r5, r0
add r4, #1
b GetPowerLoop
GetPowerLoopEnd:
mov r0, #40
mul r0, r5
mov r1, #63
ldr r3, =(0x082E7B68|1)
bl call_bx
add r0, #30
add sp, #12
pop {r4-r5, pc}
.endfunc
.pool
.func GetIvs
push {r4-r6, lr}
mov r5, r0
mov r6, r1
mov r4, #0
GetIvsLoop:
cmp r4, #6
bge GetIvsLoopEnd
mov r0, r5
mov r1, #0x27
add r1, r4
mov r2, #0
ldr r3, =(0x0806A518|1)
bl call_bx
lsl r1, r4, #1
strh r0, [r1, r6]
add r4, #1
b GetIvsLoop
GetIvsLoopEnd:
pop {r4-r6, pc}
.endfunc
.pool
.func call_bx
bx r3
.endfunc
.pool
.org 0x081C443C
ldr r3, =(SetMoveTypeIconsHack|1)
bx r3
.pool
.org 0x081C3C84
ldr r3, =(PrintMovePowerHack|1)
bx r3
.pool
.org 0x08059BE8
ldr r1, =(MoveSelectionDisplayMoveTypeHack|1)
bx r1
.pool
.close

复制代码

1696774136 · 发表于 2020-5-6 00:11:18

本站第一萌新发表于 2020-5-2 21:14
模仿jzw聚聚早期做的一个滚动式多选框（虽说是模仿其实我根本没看他的是怎么实现的，也没看效果，只是觉得 ...

请问，原版绿宝石多选对话框在哪里呢

本站第一萌新 · 发表于 2020-5-6 07:26:03

1696774136 发表于 2020-5-6 00:11
请问，原版绿宝石多选对话框在哪里呢

0x0858B760

本站第一萌新 · 发表于 2020-5-6 14:43:50

本帖最后由本站第一萌新于 2020-5-6 14:47 编辑

昼夜使用不同调色板
注意：本代码仅为研究，我看了下和某绿的实现方式不同（那个暂且不懂，只是大概看了下是每帧都在判断），安全性和实用性暂且未知，只是发出来做个记录

.gba
.thumb
.create "3.0.gba",0x8000000
.close
.open "test.gba","3.0.gba", 0x8000000
.org 0x08F80000
.func DayNight
ldr r0, =0x083DF704
cmp r0, r4
bne Normal
ldr r0, =0x03005CF8
ldrb r0, [r0, #2]
cmp r0, #6
bge Normal
UseNightPal:
ldr r0, =(NightPal + 2)
b Back
Normal:
cmp r0, #18 ;6-18点使用原调色板（白天），其余使用自定义调色板（夜晚）
bge UseNightPal
ldr r0, [r4, #8]
add r0, #2
Back:
add r5, #1
ldr r3, =(0x08088CFE|1)
bx r3
.endfunc
.pool
.align 2
NightPal:
;请在此处书写你的调色板请仿照08DD4E10写至少5个(多了不会用到，但原版有不止5个)
.org 0x08088CF4
ldr r3, =(DayNight|1)
bx r3
.pool
.close

复制代码

本站第一萌新 · 发表于 2020-5-6 17:21:42

本帖最后由本站第一萌新于 2020-5-7 15:56 编辑

之前做过的一个比较有意思的程序，随机在自定义的精灵库中抽取精灵构成双方队伍来进行对战。并且在战斗中禁用背包。之前是用C写的，我用ASM重写了一遍并删去了一些功能
以使其方便新手使用
此代码存在很大的修改空间，如可用r8储存目前的精灵数据地址。我由于是随便抽了一点时间写的所以没有进行修改。有兴趣的可以自己改进一下。

.gba
.thumb
.create "3.0.gba",0x8000000
.close
.open "test.gba","3.0.gba", 0x8000000
.macro RandomPoke, species, helditem, move1, move2, move3, move4, nature, abilityNum
.halfword species
.halfword helditem
.byte HPIV, attIV, defIV, speIV, spaIV, spdIV
.byte HPEV, attEV, defEV, speEV, spaEV, spdEV
.halfword move1, move2, move3, move4
.byte nature
.byte abilityNum
.endmacro
.macro RandomPokeEnd
.halfword 0x0
.halfword 0x0
.byte 0x0, 0x0, 0x0, 0x0, 0x0, 0x0
.byte 0x0, 0x0, 0x0, 0x0, 0x0, 0x0
.halfword 0x0, 0x0, 0x0, 0x0
.byte 0x0
.byte 0x0
.endmacro
.org 0x08F80000
.func CheckIsRandom
ldr r3, =(0x0806EA68|1)
bl call_bx
mov r0, #128
lsl r0, #7
add r0, #18 ;0x4012
ldr r3, =(0x0809D790|1)
bl call_bx
cmp r0, #0
beq CheckEnd
bl LoadParties
CheckEnd:
ldr r1, =0x030022C0
mov r2, #33
lsl r2, #5
add r2, #25 ;0x439
ldr r3, =(0x080369EC|1)
bx r3
.endfunc
.pool
.func LoadParties
push {lr}
ldr r3, =(0x08067B0C|1)
bl call_bx
ldr r3, =(0x08067B2C|1)
bl call_bx
ldr r0, =0x020244EC
bl LoadParty
ldr r0, =0x02024744
bl LoadParty
pop {pc}
.endfunc
.pool
.func LoadParty
push {r4-r7, lr}
add sp, #-4
mov r4, r0
mov r5, #0
b GetMaxIdLoop
GetSpecieLoopEnd: ;out of range
add sp, #4
pop {r4-r7, pc}
GetMaxIdLoop:
ldr r0, =gRandomPokes
mov r1, #26
mul r1, r5
add r0, r1
ldrh r0, [r0]
cmp r0, #0
beq GetMaxIdLoopEnd
add r5, #1
b GetMaxIdLoop
GetMaxIdLoopEnd:
mov r6, #0
GetSpecieLoop:
cmp r6, #6
bge GetSpecieLoopEnd
GetRandomSpecie:
ldr r3, =(0x0806F5CC|1)
bl call_bx
mov r1, r5
ldr r3, =(0x082E7BE0|1)
bl call_bx
add r1, r0, #1
mov r7, #0
CheckRepeatLoop:
cmp r7, r6
bge CheckRepeatLoopEnd
mov r3, #100
mul r3, r7
add r3, r4
ldrh r2, [r3, #30]
cmp r1, r2
beq CheckRepeatLoopEnd
add r7, #1
b CheckRepeatLoop
CheckRepeatLoopEnd:
cmp r6, r7
bne GetRandomSpecie
mov r7, r0
ldr r1, =gRandomPokes
mov r2, #26
mul r0, r2
add r0, r1
ldrb r1, [r0, #24]
str r1, [sp]
ldrh r1, [r0]
mov r0, #100
mul r0, r6
add r0, r4
mov r2, #100
mov r3, #0
mov r5, r4
ldr r4, =(0x08067E90|1)
bl call_bx2
mov r4, r5
add r0, r7, #1
mov r3, #100
mul r3, r6
add r3, r4
strh r0, [r3, #30]
mov r0, #0xFF
str r0, [sp]
mov r0, #100
mul r0, r6
add r0, r4
mov r1, #0x15
mov r2, sp
ldr r3, =(0x0806ACAC|1)
bl call_bx
mov r0, #100
mul r0, r6
add r0, r4
mov r1, #0x20
mov r2, sp
ldr r3, =(0x0806ACAC|1)
bl call_bx
ldr r2, =gRandomPokes
add r2, #2
mov r0, #26
mul r0, r7
add r2, r0
mov r1, #0xC
mov r0, #100
mul r0, r6
add r0, r4
ldr r3, =(0x0806ACAC|1)
bl call_bx
mov r5, #0
SetMoveLoop:
cmp r5, #4
bge SetMoveLoopEnd
ldr r2, =gRandomPokes
add r2, #16
mov r0, #26
mul r0, r7
add r2, r0
lsl r0, r5, #1
add r2, r0
mov r1, #0xD
add r1, r5
mov r0, #100
mul r0, r6
add r0, r4
ldr r3, =(0x0806ACAC|1)
bl call_bx
ldr r2, =gRandomPokes
add r2, #16
mov r0, #26
mul r0, r7
add r2, r0
lsl r1, r5, #1
ldrh r0, [r2, r1]
mov r1, #0xFF
mov r2, r5
ldr r3, =(0x0806B960|1)
bl call_bx
str r0, [sp]
mov r2, sp
mov r0, #100
mul r0, r6
add r0, r4
mov r1, #0x11
add r1, r5
ldr r3, =(0x0806ACAC|1)
bl call_bx
add r5, #1
b SetMoveLoop
SetMoveLoopEnd:
mov r5, #0
SetIVEVLoop:
cmp r5, #6
bge SetIVEVLoopEnd
mov r1, #0x27
add r1, r5
ldr r2, =gRandomPokes
add r2, #4
mov r0, #26
mul r0, r7
add r2, r0
add r2, r5
mov r0, #100
mul r0, r6
add r0, r4
ldr r3, =(0x0806ACAC|1)
bl call_bx
mov r1, #0x1A
add r1, r5
ldr r2, =gRandomPokes
add r2, #10
mov r0, #26
mul r0, r7
add r2, r0
add r2, r5
mov r0, #100
mul r0, r6
add r0, r4
ldr r3, =(0x0806ACAC|1)
bl call_bx
add r5, #1
b SetIVEVLoop
SetIVEVLoopEnd:
ldr r2, =gRandomPokes
add r2, #25
mov r0, #26
mul r0, r7
add r2, r0
mov r1, #0x2E
mov r0, #100
mul r0, r6
add r0, r4
ldr r3, =(0x0806ACAC|1)
bl call_bx
mov r0, #100
mul r0, r6
add r0, r4
ldr r3, =(0x08068D0C|1)
bl call_bx
add r6, #1
b GetSpecieLoop
.endfunc
.pool
.func CantUseBagHack
ldr r1, =0x021F0902
and r0, r1
cmp r0, #0
bne CantUseBag
mov r0, #128
lsl r0, #7
add r0, #18 ;0x4012
ldr r3, =(0x0809D790|1)
bl call_bx
cmp r0, #0
bne CantUseBag
ldr r3, =(0x0803C48C|1)
bx r3
CantUseBag:
ldr r3, =(0x0803C23E|1)
bx r3
.endfunc
.pool
.func call_bx
bx r3
.endfunc
.pool
.func call_bx2
bx r4
.endfunc
.pool
.align 2
gRandomPokes:
RandomPoke 0x71, 0x22C, 0x1F, 0x0, 0x1F, 0x1F, 0x0, 0x1F, 0xFC, 0x0, 0x4, 0x0, 0x0, 0xFC, 0x45, 0x5C, 0x87, 0x138, 0x14, 0x0
RandomPoke 0x321, 0x220, 0x1F, 0x0, 0x1F, 0x1F, 0x1F, 0x1F, 0xFC, 0x0, 0x4, 0x0, 0x0, 0xFC, 0x1F7, 0x186, 0x69, 0x72, 0x14, 0x1
RandomPoke 0x142, 0x149, 0x1F, 0x1F, 0x1F, 0x1F, 0x0, 0x1F, 0xFC, 0x0, 0xFC, 0x0, 0x0, 0x4, 0x11A, 0x105, 0x69, 0xB6, 0x8, 0x1
RandomPoke 0xE3, 0x22E, 0x1F, 0x1F, 0x1F, 0x1F, 0x0, 0x1F, 0xFC, 0x0, 0xFC, 0x0, 0x0, 0x4, 0x19D, 0x1BE, 0x1B0, 0x163, 0x8, 0x1
RandomPoke 0x28B, 0xC8, 0x1F, 0x1F, 0x1F, 0x0, 0x0, 0x1F, 0xFC, 0x0, 0xFC, 0x0, 0x0, 0x4, 0x168, 0x1B6, 0x49, 0xB6, 0x7, 0x0
RandomPoke 0x278, 0xC8, 0x1F, 0x0, 0x1F, 0x1F, 0x1F, 0x1F, 0xFC, 0x0, 0xFC, 0x0, 0x0, 0x4, 0x1D9, 0x19B, 0x15B, 0x69, 0x14, 0x1
RandomPokeEnd
.org 0x080369E4
ldr r3, =(CheckIsRandom|1)
bx r3
.pool
.org 0x0803C234
ldr r3, =(CantUseBagHack|1)
bx r3
.pool
.close

复制代码

如果你要新增精灵，请在gRandomPokes的末尾（RandomPokeEnd之前）以

RandomPoke 种类, 道具, HPIV, attIV, defIV, speIV, spaIV, spdIV, HPEV, attEV, defEV, speEV, spaEV, spdEV, 技能1, 技能2, 技能3, 技能4, 性格, 特性ID

复制代码

的方式书写。（性格可以去看金手指找，特性ID就是精灵种族对应的两种特性）
我已经添加了6只精灵，不过这是适用于绿宝石802的。如果你用的是绿宝石原版或者不想保留我的设定，删掉他们，但请保证至少有6只精灵
示例脚本：
#freespace 0xFF
#dynamic 0xF85000
#org @RandomBattle
setflag 0x273 //开启允许战败
setflag 0x4012 //开启随机对战
special 0x28 //储存队伍
trainerbattle 1 [训练师ID] 0 @msg1 @msg2 @ScriptAfterBattle
end

#org @ScriptAfterBattle
msgbox @msg3 2
settrainerflag [训练师ID] //设置训练师可再次对战
special 0x29 //恢复队伍
clearflag 0x4012 //禁用随机对战
clearflag 0x273 //禁用允许战败
end

#org @msg1
= ...

#org @msg2
= ...

#org @msg3
= ...
0x273这个flag在802中用于控制是否能够战败，不过我不确定绿宝石原版有没有这个flag。如果没有的话你可以自己研究或者找我，我有时间的话会帮你看看

本站第一萌新 · 发表于 2020-5-7 08:28:15

新增一个王者状态，拥有此状态的精灵的能力值将比同类多出1/4
在精灵页面和队伍中将会显示状态图标。当有其他状态存在时，将会显示其他状态的图标
战斗中遇到王者精灵将会有提示
这个也是很久前写的了，而且用的是蛇皮写法。所以逻辑性可能较差，勉强看看吧

.gba
.thumb
.loadtable "header/CharTable.txt"
.include "header/ArmipsBSMacros.asm"
.create "3.0.gba",0x8000000
.close
.open "test.gba","3.0.gba", 0x8000000
.org 0x08F80000
.func CalculateMonStatsHack1
push {r2, lr}
ldr r3, =(0x0806D8D4|1)
bl call_bx
CalculateMonStatsHack2:
ldrh r1, [r5, #30]
cmp r1, #0
beq Back
mov r1, #5
mul r0, r1
lsr r0, #2
Back:
pop {r2, pc}
.endfunc
.pool
.func HackType1
bl CalculateMonStatsHack1
mov r3, #70
mul r2, r3
ldr r3, =(0x08068E42|1)
add r3, r2
bx r3
.endfunc
.pool
.func HackType2
bl CalculateMonStatsHack1
lsl r1, r2, #2
add r1, #4
add r1, sp
str r0, [r1]
mov r3, #70
mul r2, r3
ldr r3, =(0x08068E42|1)
add r3, #2
add r3, r2
bx r3
.endfunc
.pool
.func HackHP
ldr r3, =(0x082E7540|1)
bl call_bx
add r0, r4
add r0, #0xA
mov r1, pc ;蛇皮操作，请勿学习
add r1, #9
push {r1}
push {r2}
bl CalculateMonStatsHack2
ldr r3, =(0x08068E24|1)
bx r3
.endfunc
.pool
.func RandomToBeKing
mov r1, #0x38
mov r2, sp
add r2, #10
ldr r3, =(0x0806ACAC|1)
bl call_bx
ldr r3, =(0x0806F5CC|1)
bl call_bx
ldr r1, =6666 ;概率分之一，最大0xFFFF
ldr r3, =(0x082E7BE0|1)
bl call_bx
cmp r0, #0
bne RandomEnd
mov r0, #1
mov r1, r8
strb r0, [r1, #30]
RandomEnd:
ldr r3, =(0x08067B9C|1)
bx r3
.endfunc
.pool
.func DoKingBS
mov r0, r7
ldr r3, =(0x08E1833C|1)
bl call_bx
ldrb r0, [r0, #30]
cmp r0, #0
beq BSCheckEnd
ldr r0, =0x0202420B
strb r7, [r0]
ldr r0, =BS_KINGSTATU
ldr r3, =(0x08E073E4|1)
bl call_bx
mov r4, #1
BSCheckEnd:
ldr r2, [sp, #0x10]
lsl r3, r7, #2
add r3, r2, r3
mov r2, #0x7F
ldr r0, =(0x08E051D4|1)
bx r0
.endfunc
.pool
.func MoreBattlestring
mov r3, #147
lsl r3, #2
add r1 ,r3, #1
cmp r0, r3
bgt More
mov r3, #0x7C
add r3, #0xFF
cmp r0, r3
bls Normal
ldr r3, =(0x08E0664C|1)
bx r3
Normal:
ldr r3, =(0x08E06654|1)
bx r3
More:
ldr r3, =NewBattleStringsTable
sub r0, r1
ldr r1, =(0x08E06658|1)
bx r1
.endfunc
.pool
.func CheckSpriteHack
ldr r3, =(0x081B2014|1)
bl call_bx
cmp r0, #0
bne CheckBack
ldrb r0, [r4, #30]
cmp r0, #0
beq CheckBack
mov r0, #8
CheckBack:
cmp r0, #0
ldr r3, =(0x081B2080|1)
bx r3
.endfunc
.pool
.func call_bx
bx r3
.endfunc
.pool
BS_KingStatu:
printstring 0x24D
waitmessage 0x40
end3
.align 4
NewBattleStringsTable:
.word gText_KingStatu
gText_KingStatu:
.string "王者的威压从", 0xFD, 0x0F, "身上溢出！"
.align 2
NewStatuIcons:
.word 0x00040010, 0x0000000A, 0x45030050, 0xC1440700, 0x131003C0, 0x44244450, 0x01031044, 0x42222222
.word 0x20442442, 0x0B10F203, 0x1B501750, 0x24222340, 0xD7221F30, 0x33002A20, 0x54600005, 0x13205CF0
.word 0x00AB1B10, 0x8300707F, 0x66870067, 0x131003C0, 0x26662004, 0x7B006666, 0x62206262, 0x22074062
.word 0x22226266, 0x11106650, 0x66130066, 0x4F666266, 0x26781026, 0x40010026, 0x000E1007, 0x0062571C
.word 0xE0000704, 0x205CF076, 0xD61B1013, 0x03016310, 0x28070129, 0x131003C0, 0x28220090, 0x88288822
.word 0x00848882, 0x282882FF, 0x22074028, 0x00226888, 0x82140013, 0x82220100, 0x28823A82, 0x0F500740
.word 0x10821700, 0x09572820, 0x01986001, 0x03C08864, 0x1B101310, 0xAB7F40AA, 0x80AA8701, 0x97012A03
.word 0x9B01802B, 0xAA2AAAB0, 0xA42AA2AA, 0x00220200, 0x00A22204, 0x63AA2A03, 0x000F002A, 0x22AAA217
.word 0x0A101B00, 0x109C01D7, 0x18002A09, 0x200C002A, 0x570C001C, 0x0B2C00A2, 0xC0BAE001, 0x1068105C
.word 0x1B10D513, 0x02D0FF01, 0x0702CD03, 0x5203402C, 0x2D0340CC, 0xCCC27F11, 0x06220100, 0xCC22C222
.word 0x10070022, 0xC2452C0D, 0x2C2C0F10, 0x2C09002C, 0x00A41E00, 0x1D02CC11, 0x0F10CC2C, 0x2C722CCC
.word 0x1D100A10, 0x0D222220, 0xFADC6002, 0x5C505480, 0x1B101310, 0x02507B32, 0x10B3407B, 0x07702403
.word 0x25001310, 0x86027B62, 0x228342E7, 0x2460128B, 0xF2160042, 0xCF7FA27F, 0x84027B22, 0x03C00444
.word 0x97129802, 0xEF56FF41, 0x032E0703, 0x0340EE0B, 0x802F0B10, 0xEE2E7F12, 0x222EE222, 0x10EE402E
.word 0xE2222207, 0x2F2E22E2, 0x0200E2E2, 0x101110E2, 0x10731008, 0x2300B31D, 0x0001002E, 0x00EE2E1F
.word 0x2B031018, 0x1500222E, 0xFE60030F, 0x60505880, 0x101310F7, 0xA2FFF21B, 0xE00270FF, 0xFF12E602
.word 0x2266261F, 0x03100C03, 0x1300D822, 0x10FD1B10, 0x430D031F, 0x2003200E, 0x2227032C, 0xF2C03B10
.word 0x00FFB2FF
.align 4
NewAnimCmdTable:
.incbin "test.gba", 0x61D0DC, 0x1C
.word NewAnim
.align 4
NewAnim:
.halfword 28, 0, 0xFFFF, 0
.org 0x08068E80
ldr r3, =(HackType1|1)
bx r3
.pool
.org 0x08068EC6
ldr r3, =(HackType2|1)
bx r3
.pool
.org 0x08068F0C
ldr r3, =(HackType1|1)
bx r3
.pool
.org 0x08068F52
ldr r3, =(HackType2|1)
bx r3
.pool
.org 0x08068F98
ldr r3, =(HackType1|1)
bx r3
.pool
.org 0x08068E1C
ldr r3, =(HackHP|1)
bx r3
.pool
.org 0x08067B94
ldr r3, =(RandomToBeKing|1)
bx r3
.pool
.org 0x08E051CC
ldr r3, =(DoKingBS|1)
bx r3
.pool
.org 0x08E06644
ldr r3, =(MoreBattlestring|1)
bx r3
.pool
.org 0x081B2076
ldr r3, =(CheckSpriteHack|1)
bx r3
.pool
.org 0x08615FF8
.word NewStatuIcons
.org 0x0861D0F8
.word NewStatuIcons
.halfword 0x400
.org 0x0861D110
.word NewAnimCmdTable
.close

复制代码

本站第一萌新 · 发表于 2020-5-7 20:46:57

本帖最后由本站第一萌新于 2020-5-26 22:13 编辑

在宝可梦能力界面点击A可以依次查看精灵个体，努力，再按一次回到能力。个体和努力都根据大小分为三个阶层，每个阶层用不同的颜色显示（色板里居然没有绿色，只能用蓝色代替了

）
有的地方逻辑可以修改以最大限度的节省空间和效率，比如r9那个地方，还有switch可以换成pc（之前写错了）和地址的差跳转。我一样懒得搞了
（话说这个论坛好冷啊，连发了20条左右也只有两个人回复

）

.gba
.thumb
.loadtable "header/CharTable.txt"
.create "3.0.gba",0x8000000
.close
.open "test.gba","3.0.gba", 0x8000000
.org 0x08F80000
.func CheckIsAPressedHack
mov r1, #129
lsl r1, #7
add r1, #64 ;0x40C0
ldrb r0, [r0, r1]
cmp r0, #1
bne CheckIsAPressedBack
bl ShowStates
pop {r4-r5, pc}
CheckIsAPressedBack:
ldr r3, =(0x081C05BA|1)
bx r3
.endfunc
.pool
.func ClearStatuWhenChangePage
ldr r3, =0x0203F000 ;现在看来用一个变量应该会更好？但懒得改了
mov r2, #0
strb r2, [r3]
push {r4-r7, lr}
mov r7, r10
mov r6, r9
mov r5, r8
ldr r3, =(0x081C0A94|1)
bx r3
.endfunc
.pool
.func ClearStatuWhenChangeMon
ldr r3, =0x0203F000
mov r2, #0
strb r2, [r3]
push {r4-r7, lr}
mov r7, r0
mov r5, r1
ldr r3, =(0x081C060E|1)
bx r3
.endfunc
.pool
.func ShowStates
push {lr}
ldr r0, =0x0203F000
ldrb r1, [r0]
add r1, #1
strb r1, [r0]
ldr r0, =(Task_ShowStates|1)
ldr r3, =(0x080A8FB0|1)
bl call_bx
ldr r1, =0x03005E00
mov r2, #40
mul r0, r2
add r0, r1
mov r1, #0
strh r1, [r0, #8] ;tstate
pop {pc}
.endfunc
.pool
.func Task_ShowStates
push {r4-r7, lr}
mov r4, r0
ldr r5, =0x03005E00
mov r2, #40
mul r0, r2
add r5, r0
ldrh r0, [r5, #8] ;tstate
ldr r6, =0x0203F000
ldrb r7, [r6]
ldr r1, =Switch
lsl r0, #1
ldrh r0, [r0, r1]
ldr r1, =(Task_ShowStates|1)
add r0, r1
bx r0
ClearPageWindowTilemaps:
mov r0, #1
ldr r3, =(0x081C2C38|1)
bl call_bx
b AddState
PrintHeldItemName:
ldr r3, =(0x081C35E4|1)
bl call_bx
b AddState
PrintRibbonCount:
ldr r3, =(0x081C3690|1)
bl call_bx
b AddState
BufferLeftStatsIVsEVs:
cmp r7, #0
beq BufferLeftStats
mov r0, #1
bl BufferIVsAndEVs
b AddState
BufferLeftStats:
ldr r3, =(0x081C3710|1)
bl call_bx
b AddState
PrintLeftStatsIVsEVs:
cmp r7, #0
beq PrintLeftStats
mov r0, #1
bl PrintIVsAndEVs
b AddState
PrintLeftStats:
ldr r3, =(0x081C37D8|1)
bl call_bx
b AddState
BufferRightStatsIVsEVs:
cmp r7, #0
beq BufferRightStats
mov r0, #0
bl BufferIVsAndEVs
b AddState
BufferRightStats:
ldr r3, =(0x081C3808|1)
bl call_bx
b AddState
PrintRightStatsIVsEVs:
cmp r7, #0
beq PrintRightStats
mov r0, #0
bl PrintIVsAndEVs
b AddState
PrintRightStats:
ldr r3, =(0x081C3890|1)
bl call_bx
b AddState
PrintExpPointsNextLevel:
ldr r3, =(0x081C38C0|1)
bl call_bx
b AddState
CreatePageWindowTilemaps:
mov r0, #1
ldr r3, =(0x081C2AFC|1)
bl call_bx
b AddState
DestroyTask:
cmp r7, #2
bne Destroy
mov r7, #0xFF
strb r7, [r6]
Destroy:
mov r0, r4
ldr r3, =(0x080A909C|1)
bl call_bx
AddState:
ldrh r0, [r5, #8]
add r0, #1
strh r0, [r5, #8]
pop {r4-r7, pc}
.endfunc
.pool
.func BufferIVsAndEVs
push {r4-r7, lr}
mov r4, r8
mov r5, r9
mov r6, r10
push {r4-r6}
mov r10, r0
ldr r1, =0x0203F000
ldrb r1, [r1]
cmp r0, #0
bne BufferRight
mov r0, #7
mov r9, r0
cmp r1, #1
beq HPIV
mov r4, #0x1A
b IntToString
HPIV:
mov r4, #0x27
b IntToString
BufferRight:
mov r0, #3
mov r9, r0
cmp r1, #1
beq SpeIV
mov r4, #0x1D
b IntToString
SpeIV:
mov r4, #0x2A
IntToString:
mov r5, #0
ldr r6, =0x02021CC4
ldr r7, =0x0203CF1C
ldr r7, [r7]
add r7, #0xC
IntToStringLoop:
cmp r5, #3
bge IntToStringLoopEnd
mov r0, r7
add r1, r4, r5
mov r2, #0
ldr r3, =(0x0806A518|1)
bl call_bx
mov r8, r0
bl GetLevelColour
mov r1, r0
mov r0, #0xFF
add r0, #1 ;0x100
mul r0, r5
add r0, r6
ldr r3, =(0x08008EE0|1)
bl call_bx
mov r0, #24
lsl r0, #5 ;0x300
add r0, r6
mov r1, r8
mov r2, #1
mov r3, r9
mov r8, r4
ldr r4, =(0x08008CC0|1)
bl call_bx2
mov r4, r8
mov r0, #0xFF
add r0, #1 ;0x100
mul r0, r5
add r0, r6
mov r1, #24
lsl r1, #5 ;0x300
add r1, r6
ldr r3, =(0x08008BC0|1)
bl call_bx
add r5, #1
b IntToStringLoop
IntToStringLoopEnd:
ldr r3, =(0x081AFBF0|1)
bl call_bx
mov r5, #0
SetPlaceholderPtrLoop:
cmp r5, #3
bge SetPlaceholderPtrLoopEnd
mov r1, #0xFF
add r1, #1 ;0x100
mul r1, r5
add r1, r6
mov r0, r5
ldr r3, =(0x081AFC0C|1)
bl call_bx
add r5, #1
b SetPlaceholderPtrLoop
SetPlaceholderPtrLoopEnd:
mov r0, r10
cmp r0, #0
bne LayoutRight
ldr r1, =gText_LayoutRight
b ExpandPlaceholders
LayoutRight:
ldr r1, =gText_LayoutLeft
ExpandPlaceholders:
mov r0, #24
lsl r0, #5 ;0x300
add r0, r6
ldr r3, =(0x081AFC28|1)
bl call_bx
pop {r4-r6}
mov r8, r4
mov r9, r5
mov r10, r6
pop {r4-r7, pc}
.endfunc
.pool
.func PrintIVsAndEVs
push {r4-r5, lr}
add sp, #-8
cmp r0, #0
bne PrintRight
mov r4, #4
mov r5, #2
b AddWindow
PrintRight:
mov r4, #2
mov r5, #3
AddWindow:
ldr r0, =0x0861CCEC
mov r1, r5
ldr r3, =(0x081C2D2C|1)
bl call_bx
mov r2, r4
ldr r1, =0x02021CC4
mov r3, #24
lsl r3, #5 ;0x300
add r1, r3
mov r3, #0
str r3, [sp]
str r3, [sp, #4]
mov r3, #1
ldr r4, =(0x081C25A4|1)
bl call_bx2
add sp, #8
pop {r4-r5, pc}
.endfunc
.pool
.func GetLevelColour
push {lr}
ldr r1, =0x0203F000
ldrb r1, [r1]
cmp r1, #1
bne IsEV
cmp r0, #10
ble BadColour
cmp r0, #20
ble NormalColour
b GoodColour
IsEV:
cmp r0, #85
ble BadColour
cmp r0, #170
ble NormalColour
GoodColour:
ldr r0, =gText_GoodColour
b GetLevelColourBack
BadColour:
ldr r0, =gText_BadColour
b GetLevelColourBack
NormalColour:
ldr r0, =gText_NormalColour
GetLevelColourBack:
pop {pc}
.endfunc
.pool
.func call_bx
bx r3
.endfunc
.pool
.func call_bx2
bx r4
.endfunc
.pool
.align 2
Switch:
.halfword (ClearPageWindowTilemaps - Task_ShowStates)
.halfword (PrintHeldItemName - Task_ShowStates)
.halfword (PrintRibbonCount - Task_ShowStates)
.halfword (BufferLeftStatsIVsEVs - Task_ShowStates)
.halfword (PrintLeftStatsIVsEVs - Task_ShowStates)
.halfword (BufferRightStatsIVsEVs - Task_ShowStates)
.halfword (PrintRightStatsIVsEVs - Task_ShowStates)
.halfword (PrintExpPointsNextLevel - Task_ShowStates)
.halfword (CreatePageWindowTilemaps - Task_ShowStates)
.halfword (DestroyTask - Task_ShowStates)
gText_LayoutRight:
.string 0xF7, 0x00, "\n", 0xF7, 0x01, "\n", 0xF7, 0x02
gText_LayoutLeft:
.string 0xF7, 0x01, "\n", 0xF7, 0x02, "\n", 0xF7, 0x00
gText_BadColour:
.string 0xFC, 0x01, 0x05
gText_NormalColour:
.string 0xFC, 0x01, 0x06
gText_GoodColour:
.string 0xFC, 0x01, 0x07
.org 0x081C05B0
ldr r3, =(CheckIsAPressedHack|1)
bx r3
.pool
.org 0x081C0A8C
ldr r3, =(ClearStatuWhenChangePage|1)
bx r3
.pool
.org 0x081C0604
ldr r3, =(ClearStatuWhenChangeMon|1)
bx r3
.pool
.close

复制代码

jiangzhengwenjz · 发表于 2020-5-8 06:24:18

本站第一萌新发表于 2020-5-7 20:46
在宝可梦能力界面点击A可以依次查看精灵个体，努力，再按一次回到能力。个体和努力都根据大小分为三个阶层 ...

在这里不设回复可见的话基本是不会有人回帖的

而且考虑到pokeemerald的存在，现在用ASM意义真的不大

本站第一萌新 · 发表于 2020-5-8 07:56:36

jiangzhengwenjz 发表于 2020-5-8 06:24
在这里不设回复可见的话基本是不会有人回帖的

而且考虑到pokeemerald的存在，现在用ASM意义真的不大

确实是。看到pokeemerald工程的那一刻我就感觉hook大限将至了

发这个帖子主要是考虑到论坛低端教程和高端教程之间没什么过渡，所以发一些稍微复杂一点。不过现在看起来也就是在自娱自乐了
但是感觉没有编程经验的新手凭借个人努力是很难完全搞懂pokeemerald的，不可能要求每个改版者都是专业程序员吧，就像我当初入门C的时候看聚聚发的那个个体努力显示器差点没看自闭了

各种系统完全搞不懂（其实现在也不是很懂，毕竟我是个闭门造车的典范，平时也就自己或和朋友一起瞎捉摸）（虽然说抄抄补补也能写出一些东西）
不过话说在国内我还没看到过几个用pokeemerald工程的改版，可能国内还是hook用的多一点吧

jiangzhengwenjz · 发表于 2020-5-8 11:33:47

本帖最后由 jiangzhengwenjz 于 2020-5-8 11:39 编辑

本站第一萌新发表于 2020-5-8 07:56
确实是。看到pokeemerald工程的那一刻我就感觉hook大限将至了
发这个帖子主要是考虑到论坛低 ...

额，pokeemerald只有更简单吧，因为只是用它改版你也并不需要懂他的build system，不需要懂怎么反编译，改改改就完事了，还有Egg现成的蓝本可以用，还可以用gdb调试

至于国内改版界，你如果不发这个贴我都要以为国内没人改版了（除了究绿那些人我算是知道），以前一起改版的人基本也都退了

我现在也不怎么搞改版，业余时间都在搞各种反编译项目，偶尔别人要帮忙的时候才写一下汇编
主要是现在那些函数和数据在pokeemerald/pokefirered里都命名得差不多了，再写功能就不会有太多感觉

以前，反编译还没出来，自己水平也不行，在那里调调调反而还挺有意思的

本站第一萌新 · 发表于 2020-5-8 12:00:38

jiangzhengwenjz 发表于 2020-5-8 11:33
额，pokeemerald只有更简单吧，因为只是用它改版你也并不需要懂他的build system，不需要懂怎么反编译， ...

确实感觉国内都没什么人研究GBA改版了。不过绿宝石802（应该会被最近国人在做的绿宝石890替代，毕竟有Z石梦特8代精灵等）这个蓝本已经足够满足大部分改版者的需求了，剩下的也就是写写脚本，剧情，导入素材的事了

本站第一萌新 · 发表于 2020-5-8 12:05:36

仅适用于绿宝石802
删除战死的精灵，并且如果主角战败则重置游戏（理论上能够抹除存档？但是这对模拟器而言并没有意义）

.gba
.thumb
.loadtable "header/CharTable.txt"
.include "header/ArmipsBSMacros.asm"
.create "3.0.gba",0x8000000
.close
.open "test.gba","3.0.gba", 0x8000000
.org 0x08F80000
.func DeleteFaintMon
push {lr}
bl 0x08E1833C
ldr r3, =(0x08067A8C|1)
bl call_bx
pop {pc}
.endfunc
.pool
.func DeleteAttacker
push {lr}
ldr r0, =0x0202420B
ldrb r0, [r0]
bl DeleteFaintMon
pop {pc}
.endfunc
.pool
.func DeleteTarget
push {lr}
ldr r0, =0x0202420B
ldrb r0, [r0, #1]
bl DeleteFaintMon
pop {pc}
.endfunc
.pool
.func CallasmHack
str r1, [r0]
ldr r1, =0x08E1FDFC
cmp r3, #166
blt CallasmHackBack
ldr r1, =(NewCallasmTable - 0x28)
sub r3, #166
CallasmHackBack:
lsl r2, r3, #2
add r3, r1, r2
ldr r1, =(0x08E193AC|1)
bx r1
.endfunc
.pool
.func call_bx
bx r3
.endfunc
.pool
BS_FaintAttacker:
playfaintingcry bank_attacker
pause_cmd 0x40
cmd1a bank_attacker
cmd1b bank_attacker
printstring 28
callasm_cmd 23
callasm_cmd 142
callasm_cmd 166
return_cmd
BS_FaintTarget:
playfaintingcry bank_target
pause_cmd 0x40
cmd1a bank_target
cmd1b bank_target
printstring 28
callasm_cmd 23
callasm_cmd 142
callasm_cmd 167
return_cmd
BS_CompactParty:
callasm_cmd 168
end2
BS_GotoCompactParty:
jumpifword 4, 0x02022FEC, 1, BS_CompactParty
goto_cmd BS_CompactParty
.align 4
NewCallasmTable:
.word (DeleteAttacker|1)
.word (DeleteTarget|1)
.word (0x080CE90C|1)
.org 0x08085F58
swi 0x0
.pool
.org 0x08E193A4
ldr r2, =(CallasmHack|1)
bx r2
.pool
.org 0x08049C04
.word BS_FaintAttacker
.org 0x08049C8C
.word BS_FaintTarget
.org 0x082DA7D9
.word BS_CompactParty
.org 0x082DA80F
.word BS_CompactParty
.org 0x082DA818
.word BS_CompactParty
.org 0x082DA8F0
.word BS_CompactParty
.org 0x082DA8E6
goto_cmd BS_GotoCompactParty
.close

复制代码

		自动登录	找回密码
密码			加入口袋中心

ASM杂项集合【802/绿宝石】

浏览过的版块